再次修改,适当解读,趋势参考----MA20斜率:

{MA20斜率----创幻论坛一品茶缘编写，通用副图}
{MA20斜率指标使用方法：
均线斜率判股池，正值上涨好趋势；
拉升走强超涨险，短线超跌可低吃！}
AA:=EMA(C,20);
斜率:(AA/REF(AA,1)-1)*1000,COLORFF00FF;
拉升:IF(CROSS(斜率,10),10,0),COLOR00FFFF;
超涨:IF(斜率-REF(llV(斜率,3),1)>=18,20,0),COLOR0000FF;
超跌:IF(REF(HHV(斜率,3),1)-斜率>=18,-10,0),COLOR00FF00;
20,POINTDOT,COLOR0000FF;
10,POINTDOT,COLORFFFFFF;
-10,POINTDOT,COLORFFFFFF;

{一品主力----创幻论坛一品茶缘优化经典指标系列----主力买卖，通用副图指标}
{一品主力指标使用说明：
主力买卖经典读，短中上拐可买入；
多头初现应优选，高位下拐请卖出。}
N1:=6;N2:=12;N3:=26;
MTM:=C-REF(C,1);
DX:100*EMA(EMA(MTM,N1),N1)/EMA(EMA(ABS(MTM),N1),N1),COLOR00FF00;
ZX:100*EMA(EMA(MTM,N2),N2)/EMA(EMA(ABS(MTM),N2),N2),COLOR00FFFF;
CX:100*EMA(EMA(MTM,N3),N3)/EMA(EMA(ABS(MTM),N3),N3),COLORFF00FF;
DXGD:=LLV(DX,2)=LLV(DX,5) AND CROSS(DX,MA(DX,2));
ZXGD:=LLV(ZX,2)=LLV(ZX,5) AND CROSS(ZX,MA(ZX,2)) AND DX>ZX;
短买:IF(DXGD AND BETWEEN(DX,0,60) AND ZX>0,1,0),COLORFFFFFF,POINTDOT,LINETHICK0;
中买:IF(ZXGD AND BETWEEN(DX,0,50) AND BETWEEN(CX,0,50),2,0),COLOR00FFFF,POINTDOT,LINETHICK0;
DTPL:=DX>ZX AND ZX>CX AND CX>0;
QSXS:=DX>REF(DX,1) AND ZX>REF(ZX,1);
TSJC:=CROSS(DX,CX) AND CROSS(ZX,CX);
优选:IF(CROSS(DTPL,0.8) AND (TSJC OR COUNT(QSXS,3)=3) AND CX<40,1,0),COLOR0000FF,POINTDOT,LINETHICK0;
↑:IF(LLV(DX,2)=LLV(DX,7) AND COUNT(DX<0,2) AND CROSS(DX,MA(DX,2)),1,-50),COLOR00FF00;
↓:IF(HHV(DX,2)=HHV(DX,7) AND COUNT(DX>50,2) AND CROSS(MA(DX,2),DX),50,80),COLOR0000FF;
短卖:=IF(CROSS(ZX,DX),1,0);
中卖:=IF(CROSS(CX,ZX) AND DX<ZX,2,0);
{以下设置副图显示方式}
STICKLINE(DX>0,0,DX,4,0),COLOR00FF00;
STICKLINE(ZX>0,0,ZX,4,0),COLOR00FFFF;
STICKLINE(CX>0,0,CX,4,0),COLORFF00FF;
0,COLORFFFFFF;
DRAWTEXT(短买,0,'△'),COLORFFFFFF;
DRAWTEXT(中买,0,'★'),COLOR00FFFF;
DRAWTEXT(短卖,0,'↓'),COLORFFFF00;
DRAWTEXT(中卖,0,'□'),COLORFF6600;
DRAWICON(优选,0,1);
{以下设置指标使用提示,明白以后可以删除.}
BDDW:=FILTER(DX<20 AND ZX<20,60);
DRAWTEXT(BDDW,80,'主力经典读'),COLORFFFFFF;
DRAWTEXT(BDDW,60,'上拐可买入'),COLORFFFFFF;
DRAWTEXT(REF(BDDW,15),80,'多头应优选'),COLOR00FFFF;
DRAWTEXT(REF(BDDW,15),60,'下拐请卖出'),COLOR00FFFF;

{放量攻击----创幻论坛一品茶缘编写，通用副图指标}
{N:5,60,34;}
{放量攻击指标使用说明：
量能饱和看股市，放量上涨要升值；
攻击凶猛防登顶，缩量小坑幸福池。}
A:=EMA(AMOUNT/C/1000000,7);
MID :=EMA(A,N);
UPPER:=MID + 2*STD(A,N);
LOWER:=MID - 2*STD(A,N);
量能:(A-LOWER)/(UPPER-LOWER)*100,COLORFFFFFF;
放量:IF(CROSS(量能,70),70,50),COLOR00FF00;
↑:IF(CROSS(量能,50),1,0),COLORFF00FF;
攻击:IF(CROSS(量能,100),1,0),COLOR0000FF,POINTDOT,LINETHICK0;
缩量:IF(CROSS(30,量能),1,0),COLORFFFF00,POINTDOT,LINETHICK0;
{以下设置副图显示方式}
100,POINTDOT,COLORFF00FF;
70,COLORFFFFFF;
30,POINTDOT,COLORFFFFFF;
0,POINTDOT,COLORFF6600;
STICKLINE(量能>70,70,量能,4,0),COLOR00FFFF;
STICKLINE(量能>100,100,量能,4,0),COLOR0000FF;
STICKLINE(量能<30,30,量能,4,0),COLORFFFF00;
STICKLINE(量能<0,0,量能,4,0),COLOR00FF00;
DRAWTEXT(↑,50,'↑'),COLORFF00FF;
DRAWTEXT(攻击,70, '↑'),COLOR0000FF;
DRAWTEXT(缩量,30, '↓'),COLORFFFF00;
{以下设置指标使用提示,明白以后可以删除.}
BDDW:=FILTER(缩量,60);
DRAWTEXT(BDDW,45,'量能看股市'),COLORFFFFFF;
DRAWTEXT(BDDW,25,'放量要升值'),COLORFFFFFF;
DRAWTEXT(REF(BDDW,15),45,'攻击防登顶'),COLOR00FFFF;
DRAWTEXT(REF(BDDW,15),25,'缩量幸福池'),COLOR00FFFF;

长短趋势----周期共振

{周期共振----创幻论坛一品茶缘优化经典指标系列--W&R，通用副图}
{周期共振指标使用说明：
长短周期齐共振，判断趋势易入门；
开始拉升好追涨，调整低吸找挖坑。}
WR1:100-(HHV(HIGH,34)-CLOSE)/(HHV(HIGH,34)-LlV(LOW,34))*100,COLOR0000FF;
WR2:100-(HHV(HIGH,21)-CLOSE)/(HHV(HIGH,21)-LlV(LOW,21))*100,COLORFFFFFF;
WR3:100-(HHV(HIGH,6)-CLOSE)/(HHV(HIGH,6)-LlV(LOW,6))*100,COLOR00FF00;
DXZH:=WR1-WR2<10 AND WR2-WR3<15;
LSQ:=WR1>=50 AND WR2>=50 AND WR3>=50;
拉升:IF(DXZH AND LSQ,100,50),COLORFF00FF,LINETHICK2;
↑:IF(CROSS(拉升,98),1,0),COLOR00FFFF,POINTDOT,LINETHICK0;
挖坑:IF(WR1>50 AND WR2>=50 AND WR3<=30,1,50),COLORFFFFFF,LINETHICK2;
↓:IF(COUNT(挖坑=1,2) AND WR3<=15,1,0),COLORFFFF00,POINTDOT,LINETHICK0;
{以下设置副图显示方式}
DRAWTEXT(↑,50, '●'),COLOR00FFFF;
DRAWTEXT(↑,50, '¤'),COLOR00FFFF;
DRAWTEXT(↓,10, '□'),COLORFFFF00;

{以下设置指标使用提示----熟悉以后可以删除}
BDDW:=FILTER(REF(↓,3),60);
DRAWTEXT(BDDW,40,'周期齐共振'),COLORFFFFFF;
DRAWTEXT(BDDW,20,'判势易入门'),COLORFFFFFF;
DRAWTEXT(REF(BDDW,15),40,'拉升好追涨'),COLOR00FFFF;
DRAWTEXT(REF(BDDW,15),20,'低吸找挖坑'),COLOR00FFFF;

大盘大跌,好股难寻;闲来无事,随意编写,聊备参考.----{热点五星}

{热点五星----创幻论坛一品茶缘整理，大智慧L-2版本副图}
{热点五星指标使用方法：
盘面热点选五星，随时调整跟行情；
同比提示看业绩，热门好票好拉升。}
DRAWTEXTREL(10,50,''+STKLABEL+' '+STKNAME),LINETHICK1,COLOR00FF00;
ZYTB:=FINANCE2(11);JLTB:=FINANCE2(10);
DRAWTEXTREL(200,50,'■主营同比:'+NUMTOSTRN(ZYTB,2)+'%'),COLORFFFFFF;
DRAWTEXTREL(380,50,'■净利同比:'+NUMTOSTRN(JLTB,0)+'%'),COLORFFFFFF;

奥运概念:(STRFIND(BKNAME,'奥运',1)>0),COLOR00FFFF,POINTDOT,LINETHICK0;
整体上市:(STRFIND(BKNAME,'整体上市',1)>0),COLORFF00FF,POINTDOT,LINETHICK0;
定向增发:(STRFIND(BKNAME,'定向增发',1)>0),COLOR00FF00,POINTDOT,LINETHICK0;
预盈预增:(STRFIND(BKNAME,'预盈预增',1)>0),COLOR0000FF,POINTDOT,LINETHICK0;
基金重仓:(STRFIND(BKNAME,'基金重仓',1)>0),COLORFFFF00,POINTDOT,LINETHICK0;
DRAWTEXTREL(10,250,'■热点提示:'+'xx板块'),COLOR0000FF;
DRAWTEXTREL(10,450,'■奥运概念:'+NUMTOSTRN(奥运概念,2)),COLOR00FFFF;
DRAWTEXTREL(200,450,'■整体上市:'+NUMTOSTRN(整体上市,2)),COLORFF00FF;
DRAWTEXTREL(380,450,'■定向增发:'+NUMTOSTRN(定向增发,2)),COLOR00FF00;
DRAWTEXTREL(560,450,'■预盈预增:'+NUMTOSTRN(预盈预增,2)),COLOR0000FF;
DRAWTEXTREL(740,450,'■基金重仓:'+NUMTOSTRN(基金重仓,2)),COLORFFFF00;
DRAWTEXTREL(10,800,'所属板块:'+BKNAME),COLORFFFFFF;
AA:=DISPSTATUS=2;
STICKLINE(C*AA,0,10,8,0),COLOR0000FF;
DRAWTEXT(奥运概念*AA,10,'★'),COLOR00FFFF;
DRAWTEXT(整体上市*AA,8.5,'★'),COLORFF00FF;
DRAWTEXT(定向增发*AA,7,'★'),COLOR00FF00;
DRAWTEXT(预盈预增*AA,5.5,'★'),COLORFFFFFF;
DRAWTEXT(基金重仓*AA,4,'★'),COLORFFFF00;

一品注:{热点五星},只是为了便于盘中简单参考,没有太大意义----重要的是你自己要能根据盘面热点,及时对指标内的热点板块名称提示进行修改\\变换,才有参考价值.大家随意看看吧.
图片参考:

个股强弱----创幻论坛一品茶缘优化版，副图指标}{大智慧L-2版本}
{感谢创幻论坛腾天朋友提供基础原码！}
{个股强弱指标使用说明：
个股走势比大盘，阶段强弱易分辨；
转强xx好操作，强于５０龙在天！}
C1:=(((10000 * CLOSE) / INDEXC));
Var1:=REF(c1,1);
A1:=SMA(MAX(c1-Var1,0),7,1)/SMA(ABS(c1-Var1),7,1)*100;
Var2:=REF(c1,2);
A2:=SMA(MAX(c1-Var2,0),7,1)/SMA(ABS(c1-Var2),7,1)*100;
Var3:=REF(c1,3);
A3:=SMA(MAX(c1-Var3,0),7,1)/SMA(ABS(c1-Var3),7,1)*100;
Var4:=REF(c1,4);
A4:=SMA(MAX(c1-Var4,0),7,1)/SMA(ABS(c1-Var4),7,1)*100;
XRSI1:=(A1+A2+A3+A4)/4;
FILLRGN(30,XRSI1,XRSI1>=30,188188);
FILLRGN(50,XRSI1,XRSI1>=50,883399);
FILLRGN(70,XRSI1,XRSI1>=70,003300);
XRSI:(A1+A2+A3+A4)/4,COLORYELLOW,LINETHICK1;
MX13:MA(XRSI,13),COLORRED;
xx:CROSS(XRSI,MA(XRSI,2)) AND BETWEEN(XRSI,20,60),COLORFFFFFF,POINTDOT,LINETHICK0;
QSXS:=XRSI>REF(XRSI,1) OR MX13>REF(MX13,1);
操作区:XRSI>MX13 AND QSXS,COLOR00FFFF,POINTDOT,LINETHICK0;
{以下设置副图显示方式}
STICKLINE(操作区,XRSI,MX13,4,0),COLOR00FFFF;
DRAWTEXT(CROSS(xx,0.8),XRSI,'↑'),COLORFFFFFF,ALIGN1;
DRAWTEXT(CROSS(操作区,0.8),MX13,'◆'),COLOR0000FF,ALIGN1;
弱:30,COLORFFFFFF;
强:50,COLOR00FFFF,POINTDOT;
龙:70,COLORFF00FF,POINTDOT;
险:IF(XRSI1>90,75,90),COLOR0000FF;

{个股强弱----创幻论坛一品茶缘优化版，副图指标}{通用版本}
{感谢创幻论坛腾天朋友提供基础原码！}
{个股强弱指标使用说明：
个股走势比大盘，阶段强弱易分辨；
转强xx好操作，强于５０龙在天！}
C1:=(((10000 * CLOSE) / INDEXC));
Var1:=REF(c1,1);
A1:=SMA(MAX(c1-Var1,0),7,1)/SMA(ABS(c1-Var1),7,1)*100;
Var2:=REF(c1,2);
A2:=SMA(MAX(c1-Var2,0),7,1)/SMA(ABS(c1-Var2),7,1)*100;
Var3:=REF(c1,3);
A3:=SMA(MAX(c1-Var3,0),7,1)/SMA(ABS(c1-Var3),7,1)*100;
Var4:=REF(c1,4);
A4:=SMA(MAX(c1-Var4,0),7,1)/SMA(ABS(c1-Var4),7,1)*100;
XRSI1:=(A1+A2+A3+A4)/4;
XRSI:(A1+A2+A3+A4)/4,COLORYELLOW,LINETHICK1;
MX13:MA(XRSI,13),COLORRED;
xx:CROSS(XRSI,MA(XRSI,2)) AND BETWEEN(XRSI,20,60),COLORFFFFFF,POINTDOT;
QSXS:=XRSI>REF(XRSI,1) OR MX13>REF(MX13,1);
操作区:XRSI>MX13 AND QSXS,COLOR00FFFF,POINTDOT;
STICKLINE(XRSI1>=30,30,XRSI1,4,0),COLOR00FF00;
STICKLINE(XRSI1>=50,50,XRSI1,4,0),COLORFF00FF;
STICKLINE(XRSI1>=70,70,XRSI1,4,0),COLOR0000FF;
STICKLINE(操作区,XRSI,MX13,4,1),COLOR00FFFF;
DRAWTEXT(CROSS(xx,0.8),XRSI,'↑'),COLORFFFFFF;
DRAWTEXT(CROSS(操作区,0.8),MX13,'◆'),COLOR0000FF;
弱:30,COLORFFFFFF;
强:50,COLOR00FFFF,POINTDOT;
龙:70,COLORFF00FF,POINTDOT;
险:IF(XRSI1>90,75,90),COLOR0000FF;

连续暴超----清澈见底

{清澈见底----一品茶缘编写，通用副图指标}
{清澈见底指标使用说明：
连续跳空四连阴，股价超跌寒人心；
清澈好水先xx，见底出现抢黄金！}
TKQK:=O<REF(C,1) AND C<REF(C,1);
DFXD:=(C/REF(C,1)-1)*100<=-4;
DRDD:=(C/REF(C,1)-1)*100<=-6;
清澈:COUNT(TKQK OR DFXD,4)=4 AND COUNT(DRDD,4),COLORFFFFFF;
JD1:=C>O AND C>REF(C,1);
JD2:=(MIN(C,O)-L)/ABS(C-O)>=1.5;
见底:(JD1 OR JD2) AND REF(清澈,1),COLOR00FFFF;
MA60:=MA(C,60);
QSXS:=C>=MA60 AND MA60>REF(MA60,1);
优选:见底 AND QSXS,COLORFF00FF,POINTDOT,LINETHICK0;
DRAWICON(优选,0.1,1);