装系统时,大部份是台式机,而且是些比较老的机器,所以关闭一些不常用的系统服务,其中,无线网络有的人用到,有的用不到,开着又占用资源,需要用时又不知道该如何打开,所以用AU3写了个打开关闭无线网络服务的小程序.

运行界面

先检测相关的系统服务是否启动,用个图来表示,灰色,表示无线不可用,这样更直观一些.如上图,我本机的无线服务是关闭的,点击 开启服务后,打开无线网络的服务,图也变成绿色的.

将这个小程序放在C:\Program files\Admin_Tools\Wlan_set目录里,然后在菜单里加上,这样方便使用了.

源码如下:

#Region ;**** 参数创建于 ACNWrapper_GUI ****
#AutoIt3Wrapper_Icon=D:\autoit3\Aut2Exe\Icons\norton3.ico
#AutoIt3Wrapper_Outfile=wlanset.exe
#AutoIt3Wrapper_Res_Comment=无线服务设置
#AutoIt3Wrapper_Res_Description=用于Winxp无线网络相关服务设置
#AutoIt3Wrapper_Res_Fileversion=1.0
#AutoIt3Wrapper_Run_Tidy=y
#EndRegion ;**** 参数创建于 ACNWrapper_GUI ****
Opt("TrayIconHide", 1) ;隐藏托盘图标
Opt("GUICloseOnESC", 0) ;按下WSC键时,不停止程序运行
Opt("OnExitFunc", "Quit") ;设置在Autoit退出时,运行Quite函数
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <servicecontrol.au3>

FileInstall("SkinCrafterDll.dll", @TempDir & "SkinCrafterDll.dll", 1)
FileInstall("vista.skf", @TempDir & "vista.skf", 1)
FileInstall("wlan_enable.jpg", @TempDir & "wlan_enable.jpg")
FileInstall("wlan_disable.jpg", @TempDir & "wlan_disable.jpg")

Global $Dll = @TempDir & "SkinCrafterDll.dll"
Dim $bf = @TempDir & "vista.skf" ;皮肤文件路径
Global $srv_name[5]
$srv_name[1] = "SSDPSRV"
$srv_name[2] = "Dhcp"
$srv_name[3] = "Dnscache"
$srv_name[4] = "WZCSVC"

$Form1 = GUICreate("无线网卡及相关服务设置", 314, 210, 288, 156)

_SkinGUI($Dll, $bf, $Form1)
$Group1 = GUICtrlCreateGroup("无线服务状态:", 16, 16, 280, 121)
srv_check()
$Group2 = GUICtrlCreateGroup("", 16, 145, 280, 50)
$Wlan_on = GUICtrlCreateButton("开启服务(&O)", 30, 160, 75, 25, 0)
$Wlan_off = GUICtrlCreateButton("关闭服务(&C)", 120, 160, 75, 25, 0)
$Wlan_exit = GUICtrlCreateButton("退 出(&X)", 209, 160, 75, 25, 0)
GUICtrlSetColor(-1, 0x3D95FF)
GUISetState(@SW_SHOW)

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
   Case $GUI_EVENT_CLOSE
    Exit
   Case $Wlan_exit
    Exit
   Case $Wlan_on
    wlan_on()
    srv_check()
    GUICtrlSetState($Wlan_on, $GUI_DISABLE)
    GUICtrlSetState($Wlan_off, $GUI_ENABLE)
   Case $Wlan_off
    wlan_off()
    srv_check()
    GUICtrlSetState($Wlan_off, $GUI_DISABLE)
    GUICtrlSetState($Wlan_on, $GUI_ENABLE)
EndSwitch
WEnd

;开启无线服务函数
Func wlan_on()
For $i = 1 To 4
   _SerSetState($srv_name[$i], 1)
   _servstart($srv_name[$i])
Next
EndFunc   ;==>wlan_on

;关闭无线服务函数
Func wlan_off()
For $i = 1 To 4
   _SerSetState($srv_name[$i], 3)
   _servstop($srv_name[$i])
Next
EndFunc   ;==>wlan_off

;检测服务状态
Func srv_check()
Dim $i, $pic_path, $srv_state[5]

For $i = 1 To 4
   $srv_state[$i] = _ServGetState($srv_name[$i])
   ;MsgBox(4096, "Test", $srv_name[$i] & "服务状态: " & _ServGetState($srv_name[$i])) ;测试服务状态
Next

If $srv_state[1] = "running" And $srv_state[2] = "running" And $srv_state[3] = "running" And $srv_state[4] = "running" Then
   $Pic1 = GUICtrlCreatePic("", 100, 35, 100, 62, BitOR($SS_NOTIFY, $WS_GROUP))
   GUICtrlSetImage($Pic1, @TempDir & "wlan_enable.jpg")
   $Label2 = GUICtrlCreateLabel("无线服务可用", 120, 110, 100, 17)
   GUICtrlSetColor(-1, 0x00FF00)
Else
   $Pic1 = GUICtrlCreatePic("", 100, 35, 100, 62, BitOR($SS_NOTIFY, $WS_GROUP))
   GUICtrlSetImage($Pic1, @TempDir & "wlan_disable.jpg")
   $Label2 = GUICtrlCreateLabel("无线服务不可用", 120, 110, 100, 17)
   GUICtrlSetColor(-1, 0xFF0000)
EndIf
EndFunc   ;==>srv_check

Func _SkinGUI($SkincrafterDll, $SkincrafterSkin, $Handle)
$Dll = DllOpen($SkincrafterDll)
DllCall($Dll, "int:cdecl", "InitLicenKeys", "wstr", "1", "wstr", "", "wstr", "", "wstr", "1")
DllCall($Dll, "int:cdecl", "InitDecoration", "int", 1)
DllCall($Dll, "int:cdecl", "LoadSkinFromFile", "wstr", $SkincrafterSkin)
DllCall($Dll, "int:cdecl", "DecorateAs", "int", $Handle, "int", 25)
DllCall($Dll, "int:cdecl", "ApplySkin")
EndFunc   ;==>_SkinGUI

;退出清理文件
Func Quit()
GUISetState(@SW_HIDE)
DllCall($Dll, "int:cdecl", "DeInitDecoration")
DllCall($Dll, "int:cdecl", "RemoveSkin")
DllClose($Dll)
FileDelete(@TempDir & "SkinCrafterDll.dll")
FileDelete(@TempDir & "vista.skf")
FileDelete(@TempDir & "wlan_enable.jpg")
FileDelete(@TempDir & "wlan_disable.jpg")
Exit
EndFunc   ;==>Quit