拉升在即--【斜面推高】主副图
（附注：2007年以来，斜面推高-推高信号20天10%成功率达到95%以上，其他数字有兴趣的朋友可以自己测试。）

{一品【斜面推高Z】----创幻论坛一品茶缘编写精品指标，大智慧主图指标}{飞弧通用}
{参数:N:1,20,10;P:1,8,4;}
{斜面推高指标使用说明：
均线多头向上行，斜面出现好行情；
连续小幅在推高，及时买入享拉升！}
MA5:MA(C,5);
MA10:MA(C,10);
MA20:MA(C,20);
MA30:MA(C,30);
DTPL:=MA10>MA20 AND MA20>MA30 AND MA20>REF(MA20,1) AND MA30>REF(MA30,1);
DTSJ:=BARSLAST(CROSS(DTPL,0.1));
斜面:DTSJ*DTPL>0,COLOR00FFFF,POINTDOT,LINETHICK0;
ZF:=(C/REF(C,1)-1)*100;
WBTG:=COUNT(C>MA10 AND MA10>REF(MA10,1),3)=3;
LXXZ:=COUNT(ABS(ZF)<P,N)>=N-2;
推高:(LXXZ AND WBTG AND 斜面 AND COUNT(ZF>5,3)=0)*1,COLOR00FF00,POINTDOT,LINETHICK0;
BCXM:=COUNT(斜面,5)=5;
SL:=V<REF(V,1);
缩量:((COUNT(SL,5)>=3 OR COUNT(SL,6)>=4) AND SL AND V<MA(V,5))*1,COLORFFFFFF,POINTDOT,LINETHICK2;
优选:推高 AND BCXM AND 缩量,COLORFF00FF,POINTDOT,LINETHICK2;
{以下设置主图显示方式}
STICKLINE(斜面,MA20,(MA20+MA30)/2,4,0),COLOR00FFFF;
STICKLINE(斜面,MA30,(MA20+MA30)/2,4,0),COLORFF00FF;
STICKLINE(斜面 AND 缩量,(MA20+MA30)/2*1.005,(MA20+MA30)/2*0.995,4,1),COLORFFFFFF;
DRAWTEXT(推高,l,'△'),COLOR00FF00;
DRAWICON(优选,L,1);

{一品【斜面推高】----创幻论坛一品茶缘编写精品指标，大智慧主图指标}{飞弧通用}
{参数:N:1,20,10;P:1,8,4;}
{斜面推高指标使用说明：
均线多头向上行，斜面出现好行情；
连续小幅在推高，及时买入享拉升！}
MA5:=MA(C,5);
MA10:=MA(C,10);
MA20:=MA(C,20);
MA30:=MA(C,30);
DTPL:=MA10>MA20 AND MA20>MA30 AND MA20>REF(MA20,1) AND MA30>REF(MA30,1);
DTSJ:=BARSLAST(CROSS(DTPL,0.1));
斜面:DTSJ*DTPL,COLOR00FFFF,POINTDOT,LINETHICK2;
ZF:=(C/REF(C,1)-1)*100;
WBTG:=COUNT(C>MA10 AND MA10>REF(MA10,1),3)=3;
LXXZ:=COUNT(ABS(ZF)<P,N)>=N-2;
推高:(LXXZ AND WBTG AND 斜面 AND COUNT(ZF>5,3)=0)*DTSJ,COLOR00FF00,LINETHICK1;
BCXM:=COUNT(斜面,5)=5;
SL:=V<REF(V,1);
缩量:((COUNT(SL,5)>=3 OR COUNT(SL,6)>=4) AND SL AND V<MA(V,5))*1,COLORFFFFFF,POINTDOT,LINETHICK2;
优选:推高 AND BCXM AND 缩量,COLORFF00FF,POINTDOT,LINETHICK2;
{以下设置副图显示方式}
STICKLINE(斜面,斜面*1.001,斜面*0.999,4,1),color00FFFF;
STICKLINE(缩量,0,1,4,1),COLORFFFFFF;
STICKLINE(缩量,0,-1,4,1),COLOR00FF00;
DRAWICON(优选,5,1);

{期待突破----一品茶缘编写,大智慧\\飞狐通用副图}
{N:5,30,8;ZF:1,10,5;}
放量上涨:CLOSE/REF(CLOSE,1)>=1.01 AND VOL/REF(VOL,1)>=1.5 AND VOL>MA(VOL,5) AND REF(VOL,1)/REF(MA(VOL,5),1)<=1.8,STICK,ColorYELLOW,LINETHICK3;
箱体形成:((HHV(C,3)/LLV(C,N)-1)*100<=ZF AND (HHV(C,N)/LLV(C,3)-1)*100<=ZF)*0.3,COLOR00FF00,STICK,LINETHICK2;
STICKLINE(箱体形成=0.3 ,0 ,0.3 ,5 ,1 ),color00FF00;
接近箱顶:(CLOSE/REF(HHV(CLOSE,N),2)<=1.02 AND HIGH/REF(HHV(CLOSE,N),2)>=0.98)*0.5,COLORWHITE,LINETHICK1;
P1:=BARSLAST(箱体形成=0.3);
P2:=BARSLAST(接近箱顶=0.5);
期待突破:(放量上涨 AND 接近箱顶=0.5 AND P1<=3 AND P2<=1)*2,COLORRED,LINETHICK2;
关注:(放量上涨 AND 接近箱顶=0.5 AND 期待突破=0)*1,COLORFF00FF,LINETHICK2;
DRAWTEXT(期待突破>0 ,1.5 , '★买'),COLORYELLOW,LINETHICK2;
DRAWTEXT(关注 ,0.8 , '关注'),COLORWHITE,LINETHICK2;
趋势向上:(MA(C,30)>REF(MA(C,30),1))*0.5, CIRCLEDOT,COLORYELLOW;

简单主图--35秘密Z

{35秘密Z----创幻论坛一品茶缘编写,大智慧主图}{通用}
MA3:MA(C,3),COLOR00FF00;
MA5:MA(C,5),COLORFFFFFF;
ZX:=(MA3+MA5)/2;
MA20:MA(C,20),COLORFF00FF;
MA30:MA(C,30),COLORYELLOW;
QSXS:=MA5>=MA30 AND MA30>REF(MA30,1);
GD:=ZX>=REF(ZX,1) AND REF(ZX,1)<REF(ZX,2);
YB:=C>REF((O-C)/2+C,2);
买:CROSS(C,ZX) AND (GD OR YB) AND QSXS,COLOR00FF00,POINTDOT,LINETHICK0;
优:买 AND MA5>REF(MA5,1),COLORYELLOW,POINTDOT,linethick0;
{以下设置主图显示方式}
STICKLINE(买,h,l,0,1),COLOR00FF00,linethick2;
STICKLINE(买,o,c,4,1),COLOR00FF00,linethick2;
STICKLINE(优,h,l,0,1),COLORYELLOW,linethick2;
STICKLINE(优,o,c,4,1),COLORYELLOW,linethick2;
DRAWTEXT(买,L*0.99, '买'),COLOR00FF00;
DRAWICON(优,L,1);

双核心,更分明----一品ＭＡＣＤ

{一品MACD----创幻论坛一品茶缘编写，大智慧副图}{飞狐通用}
{N:1,20,10;参数N表示洗盘前拉升时间不超过N天；}
{一品MACD指标使用方法：
ＭＡＣＤ巧变形，趋势判断更分明；
启动初涨拉升快，洗盘低买高位清。}
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:200*(DIFF-DEA),COLORSTICK;
趋势:2*(MACD-REF(MACD,1)),COLORFFFFFF,LINETHICK2;
启动:IF(CROSS(趋势,0) AND MACD<0,10,0),COLOR00FF00;
拉升:IF(CROSS(MACD,0),10,0),COLOR00FFFF;
SZSJ:=BARSLAST(CROSS(趋势,0))+1;
LSSJ:=BARSLAST(CROSS(MACD,0))+1;
洗盘:IF(趋势<0 AND SZSJ<N AND LSSJ<N,-10,0),COLORFF00FF;
推高:IF(CROSS(趋势,0) AND MACD>0,10,0),COLOR0000FF;
小心:IF(CROSS(0,趋势) AND (SZSJ>=N OR LSSJ>=N) AND MACD>0,-10,0),COLORFFFF00;
{以下设置副图显示方式}
STICKLINE(趋势>0,趋势,0,2,0),COLOR00FFFF;
STICKLINE(趋势<0,趋势,0,2,0),COLOR008800;
STICKLINE(洗盘<0 AND C<REF(C,1),洗盘,0,2,1),COLORFF00FF;
STICKLINE(小心<0,趋势,0,2,0),COLORFFFF00;
DRAWTEXT(拉升,0,'△'),COLOR00FFFF;
DRAWTEXT(推高,0,'★'),COLOR0000FF;
DRAWTEXT(REF(CROSS(MACD,0),1),MACD*2,'高卖？'),COLORFF00FF;
DRAWTEXT(REF(CROSS(0,MACD),1),MACD,'低买？'),COLORFFFFFF;

重读经典----简单KDJ

{简单KDJ----创幻论坛一品茶缘编写,通用副图指标}
{该指标优化基础思路来自股往金未来先生,特此致谢.}
{简单KDJ指标使用方法：
重读经典ＫＤＪ，Ｊ值转向定策略；
超跌关注重启买，加码小心更明确！}
RSV:=(C-LLV(L,9))/(HHV(H,9)-LLV(L,9))*100;
K:SMA(RSV,3,1),COLORFFFFFF;
D:SMA(K,3,1),COLOR00FFFF;
J:3*K-2*D,COLORFF00FF;
超跌:IF(J<0,10,0),COLORFFFF00;
BDDD:=LLV(J,2)=LLV(J,8);
重启:IF(CROSS(J,REF(J+0.01,1)) AND BDDD AND J<20,30,0),COLOR00FF00;
加码:IF(CROSS(J,REF(J+0.01,1)) AND BDDD AND BETWEEN(J,20,60),1,0),COLOR00FFFF,POINTDOT,LINETHICK0;
BDGD:=HHV(J,2)=HHV(J,8) AND J>80;
小心:IF(CROSS(REF(J-0.01,1),J) AND REF(BDGD,1),70,100),COLOR0000FF;
DRAWTEXT(加码,J,'△'),COLOR00FFFF;

成本均线----建仓拉升

{建仓拉升----创幻论坛一品茶缘编写,大智慧主图指标}
{建仓拉升指标使用方法：
成本均线ＣＹＣ，空头排列建仓期；
空转多头建仓毕，短线拐点拉升急！}

CYC5:CYC(5);
CYC13:CYC(13);
CYC34:CYC(34);
CYC0:MAXCYC,COLORFF9900;
DTPL:=CYC5>CYC13 AND CYC13>CYC34 AND CYC34>CYC0;
建仓:CROSS(DTPL,0.9),COLOR00FFFF,POINTDOT,LINETHICK0;
LS1:=CROSS(CYC5,REF(CYC5+0.01,1));
LS2:=CROSS(C,CYC5) AND (C=HHV(C,4) OR C>REF(C,4));
拉升:FILTER(LS1 OR LS2,3) AND COUNT(DTPL,5)>=4,COLORFF00FF,POINTDOT,LINETHICK0;
{以下设置主图显示方式}
DRAWTEXT(建仓,CYC0,'★建仓完毕'),COLOR00FFFF;
DRAWICON(拉升,CYC34,1);
DRAWTEXT(拉升,CYC13,'↑'),COLORFFFFFF;

选龙助手----阶段统计

{阶段统计----创幻论坛一品茶缘编写，副图指标} {通用}
{N1:1900,2500,2007;Y1:1,12,1;R1:1,31,8;----本行参数表示统计开始的年月日；}
{N2:1900,2500,2007;Y2:1,12,3;R2:1,31,30;----本行参数表示统计结束的年月日；}
{DDF:10,30,18;----表示阶段高点回落的跌幅;一般股票牛市可以只选择10，18为超跌安全买点；}
{阶段统计指标使用说明：
参数调整变周期，阶段统计比高低；
同期对比选龙头，黄坑提示可低吸。}
年:=YEAR;
月:=MONTH;
日:=DAY;
始:=年=N1 AND 月=Y1 AND 日=R1;
终:=年=N2 AND 月=Y2 AND 日=R2;
期:BARSLAST(始),COLORFFFFFF;
停:=BARSLAST(终);
涨: (C/REF(C,期)-1)*100,COLOR00FFFF;
高: (HHV(H,期)/REF(C,期)-1)*100*(期>=1),COLORFF00FF;
HLSJ:=BARSLAST(CROSS(高=REF(高,1),0.5))+1;
HJK:=(REF(H,HLSJ)/L-1)*100-DDF;
坑: (HJK>0)*HJK,COLOR00FFFF;
{以下设置副图显示方式}
STICKLINE(始,0,50,1,0),COLOR00FF00;
STICKLINE(终,0,50,1,0),COLORFF00FF;
DRAWTEXT(始,80,'开始'),COLOR00FF00;
DRAWTEXT(终,80,'结束'),COLORFF00FF;
STICKLINE(坑,涨,高-DDF,4,0),COLOR00FFFF;
0,COLORFFFFFF;

关于阶段统计与选股：
1、该指标只是对于目标股进行一个阶段的涨幅进行简单的统计（飞弧软件有此功能），并非属于买卖点的选择与确定的指标，没有必要做成选股公式；
2、因为时间段是灵活的，所以该指标同样无法编写固定的选股公式，就是无法适用于自动预警（也没有必要），还请大家在使用时根据自己的需要调整开始与结束的周期参数，然后再选股，同样很快的啊。

具体选股方法如下：
（1）首先确定你要统计的时间段，调整开始、结束的参数周期；
（2）开始选股：
A、统计时间确定为该时段结束的日子；
B、条件选择：高----大于----50（就是你选择的目标在本阶段内的{zd0}涨幅达到+50%以上，一般就是龙头）；
C、选股到指定板块----确定；这样就可以选出你需要的目标股了。

3、选择出龙头目标股后的作用：
（1）一品觉得这样的阶段特大涨幅龙头目标股，在适当休息后，一般都有再次爆发的可能，所以值得连续跟踪；然后利用其他能够确定买卖点的指标来确定自己的操作；
（2）可以确定某个板块中的龙头目标，然后思考与她关联密切的目标股，对比涨幅，看能否有补涨机会；
例如：一品的股市三人行中的000562、000563与600030//600266、600263与600386//600651、600654与000532……基本都有这样的参考与对比的价值。
（3）龙头可能涨得更快，走在前面；而龙头休息的时候，与她关联密切的、同一板块的个股，可能就要补涨；这就是问题的答案。所以我们要注意的就是把握好龙头的领涨与非龙头的补涨之间的节奏问题了。最近的航天军工概念的600765（龙头）与002013（非龙头）、600038（非龙头），就有这样的明显关联。

以上思路，仅供大家参考。一品真诚欢迎大家的批评与交流！

{一品倍增Z----创幻论坛一品茶缘编写精品指标，通用主图}
{一品注：该指标思路来源于黄家坚先生《股市倍增术》一书，一本书一个指标全部体现！}
{指标使用方法：
一品倍增有诀窍，年线上拐好股票；
股价突破加上拐，中线买点就一招。
买点前期找低点，低点翻番作目标；
涨幅八十先预警，能够翻番乐逍遥！
蜻蜓点水好低吸，四渡赤水牛难找；
鱼跃龙门再翻番，神龙飞天上九霄！}
P1:=5;P2:=10;P3:=20;P4:=30;
MA250:EMA(C,250),COLOR0000FF,LINETHICK2;
GD250:=MA250>=REF(MA250,1) AND REF(MA250,1)<REF(MA250,2);
XS250:=MA250>REF(MA250,1);
TP250:=CROSS(C,MA250);
HC250:=COUNT(C>MA250,10)>=8 AND (CROSS(L,MA250*1.02) OR CROSS(L,MA250));
YXTP:=FILTER(COUNT(TP250,3) AND COUNT(C>MA250,3)=3,5);
YXHC:=FILTER(COUNT(HC250,3) AND COUNT(C<MA250,3)=3,5);
HCBP:=FILTER(COUNT(HC250,3) AND C>MA250,5);
JDDD:=L=LLV(L,30) AND COUNT(L<MA250,5)=5;
DDSJ:=BARSLAST(JDDD);
MD1:=YXTP AND XS250;
MD2:=COUNT(C>MA250,3)=3 AND GD250;
买点:FILTER(MD1 OR MD2,5),COLORFF00FF,POINTDOT,LINETHICK0;
MDSJ:=BARSLAST(买点);
低点:REF(L,DDSJ)*(MDSJ<DDSJ),COLOR00FF00,POINTDOT,LINETHICK0;
IF(DDSJ>0,DDSJ,DDSJ)*(MDSJ<DDSJ),COLORFFFFFF,POINTDOT,LINETHICK0;
目标:低点*2,COLORFF00FF,POINTDOT,LINETHICK0;
涨:(C/低点-1),COLOR0000FF,POINTDOT,LINETHICK0;
警:低点*1.8,COLOR00FFFF,POINTDOT,LINETHICK0;
四渡赤水:=COUNT(YXTP OR YXHC,120)>=4 AND YXTP;
达标:=FILTER(CROSS(H,目标) AND NOT(低点=0),10);
DBSJ:=BARSLAST(达标);
BDXG:=H=HHV(H,30) AND DBSJ<3;
XGSJ:=BARSLAST(BDXG);
REF(H,XGSJ),COLOR00FF00,POINTDOT;
鱼跃龙门:CROSS(C,REF(H+0.001,XGSJ)),COLORFF00FF,POINTDOT,LINETHICK0;

{以下设置主图显示方式}
MA1:MA(C,P1),COLOR00FFFF;
MA2:MA(C,P2),COLORFF00FF;
MA3:MA(C,P3),COLOR00FF00;
MA4:MA(C,P4),COLORFFFFFF;
DRAWTEXT(GD250,MA250 , '拐△点'),COLORFFFFFF;
DRAWTEXT(YXTP,L*0.96 , '突●破'),COLOR00FFFF;
DRAWTEXT(买点,L*0.99 , '买★点'),COLORFF00FF;
DRAWTEXT(HCBP,L*0.98 , '蜻蜓◆点水'),COLOR00FF00;
DRAWTEXT(四渡赤水,L*0.92 , '四渡●赤水'),COLORFFFFFF;
DRAWTEXT(四渡赤水,L*0.92 , '四渡¤赤水'),COLORFFFFFF;
DRAWICON(买点,L*0.99,1);
DRAWTEXT(达标,H*1.02 , '达●标'),COLOR00FFFF;
DRAWTEXT(鱼跃龙门,L*0.99 , '鱼跃★龙门'),COLORFF00FF;
DRAWICON(鱼跃龙门,L*0.99,1);

一品注:指标文字较多,是为了便于初次观察理解,熟悉后建议修改如下:
'拐△点'----△
'突●破'----●
'买★点'----买
'蜻蜓◆点水'----◆
'四渡●赤水'----●
'四渡¤赤水'----¤
'达●标'----达●标
'鱼跃★龙门'----★

{KD追涨----创幻论坛一品茶缘编写，大智慧副图}{通用}
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:=(SMA(RSV,3,1));
D:=(SMA(K,3,1));
KK:=INTPART(SMA(RSV,3,1));
DD:=INTPART(SMA(K,3,1));
N:KK+DD,COLORff00ff,LINETHICK2;
SZ:=(C/REF(C,1)-1)*100>=2;
QSXS:=N>REF(N,1) AND BETWEEN(N,100,150);
ZZ:=QSXS AND SZ;
追涨:IF(FILTER(ZZ,3),120,50),COLORYELLOW;
GWGD2:=N<REF(N,1) AND REF(N,1)>=160 AND REF(N,1)>=REF(N,2);
风险:IF(GWGD2,95,160),COLOR00ff00;
{以下设置副图显示方式}
100,COLORWHITE,POINTDOT;
STICKLINE(C,100,100,4,0),COLORWHITE;

MA20斜率}
AA:=EMA(C,20);
斜率:(AA/REF(AA,1)-1)*1000,COLOR00FFFF;
5,POINTDOT,COLORFF00FF;
0,POINTDOT,COLOR00FF00;
-5,POINTDOT,COLORFFFFFF;